# proBubble.ts by Promethius
# Dec 2008
# Find bubbles after ZTM
# Bubble finder / bubble sector list

# To do:  Add option to restrict gates displayed by the number of adjacent warps
#

# Setup menu vars and version
setVar $minBubbleSize 3
setVar $maxBubbleSize 500
setVar $version "ProBubble v1.0"

:menu
echo ANSI_14 "**   " $version ANSI_11 "  by Promethius*"
echo ANSI_12 "*1. " ANSI_15 "Enter the minimum bubble size.  Current is: " ANSI_12 $minBubbleSize
echo ANSI_12 "*2. " ANSI_15 "Enter the maximum bubble size.  Current is: " ANSI_12 $maxBubbleSize
echo ANSI_12 "*3. " ANSI_13 "Run it*"
getConsoleInput $menuChoice SINGLEKEY

if ($menuChoice = 1)
   echo ANSI_11 "*Enter the new " ANSI_12 "minimum " ANSI_11 "bubble size*"
   getConsoleInput $minBubbleSize
elseif ($menuChoice = 2)
   echo ANSI_11 "*Enter the new " ANSI_12 "maximum " ANSI_11 "bubble size*"
   getConsoleInput $maxBubbleSize
elseif ($menuChoice = 3)
   goto :runIt
end
goto :menu

:runIt
setVar $totalBubbles 0
# delete the current file if it exists
delete GAMENAME & "_bubbleSectors" & ".txt"

# don't care about gates from Fed so set to 11
setVar $idx 11
# clear all internal TWX avoids
clearallavoids

while ($idx <= SECTORS)
   # don't want "gates" with only 1-warp sector that can be blocked or has backdoors
   if (sector.warpcount[$idx] > 1) and (sector.backdoorcount[$idx] = 0)
      setAvoid $idx
      setVar $warpCnt sector.warpcount[$idx]
      setVar $counter 1

   while ($counter <= $warpCnt)
          # get our adjacent sectors to the gate
          setVar $adj sector.warps[$idx][$counter]
         if (sector.warpCount[$adj] > 1) and (sector.backdoorcount[$adj] = 0)
            # check course from terra to our adjacent after voiding the gate above ($idx)
            getCourse $course 1 $adj
            if ($course < 0)
               # no warps to our adjacent, check from adjacent to terra
               getCourse $course $adj 1
               if ($course < 0)
                  gosub :checkBubbles
               end
            end
         end
         add $counter 1
   end
   # clear the void from our gate
   clearAvoid $idx
   end
add $idx 1
end

# we are done so give the user some information
echo ANSI_11 "** Possible gateways: " $totalBubbles "*"
echo ANSI_15 "*File saved as: " ANSI_14 GAMENAME & "_bubbleSectors" & ".txt *"
clearallavoids
halt

:checkbubbles
setVar $i 1
setVar $move 0
setVar $bubbleSectorCnt 0
setVar $ptr 0
setVar $test ""
setVar $bubbleGate $idx
setArray $atTop SECTORS
setArray $sectorFound SECTORS

# get sector(s) ajacent to gate in bubble
# mark our gate as found (True)
setVar $sectorFound[$bubbleGate] TRUE
setAvoid $bubbleGate
# loop all adjacent sectors to find our bubble start(s)
while ($i <= sector.warpcount[$bubbleGate])
   getCourse $chkCourse 1 sector.warps[$bubbleGate][$i]
   if ($chkCourse < 0)
      add $move 1
      setVar $atTop[$move] sector.warps[$bubbleGate][$i]
      setVar $sectorFound[$atTop[$move]] TRUE
      setVar $test $test & $atTop[$move] & " "
   end
     add $i 1
end

:topQueue
   if ($test = "")
      return
   end
   setVar $bubbleSectorCnt $move
   setVar $ptr 1
   # if our current sector <> 0, walk through the bubble
   while ($atTop[$ptr] <> 0)
      gosub :childQueue
   end

   goto :writefile

:childQueue
  setVar $i 1
  # basically the same as for the gate, but for the "child" sectors on voiding
  while ($i <= sector.warpcount[$atTop[$ptr]])
          # make sure the adjacent isn't a 1-way from the current sector
          getdistance $dist sector.warps[$atTop[$ptr]][$i] $atTop[$ptr]
          if ($dist = 1) and ($sectorFound[sector.warps[$atTop[$ptr]][$i]] = FALSE)
             add $move 1
             add $bubbleSectorCnt 1
             # add the sectors found to our "top" queue to have its "children" checked
             setVar $atTop[$move] sector.warps[$atTop[$ptr]][$i]
             # mark found as true so we don't include it several times in our list
             setVar $sectorFound[sector.warps[$atTop[$ptr]][$i]] TRUE
          end
          add $i 1
  end
        add $ptr 1
  return

:writeFile
    # write a list of sectors
    # clear the void for the bubble gate
    clearAvoid $bubbleGate
    # if the size isn't within our menu parameters, return
    if ($bubbleSectorCnt < $minBubbleSize) or ($bubbleSectorCnt > $maxBubbleSize)
       return
    end
    add $totalBubbles 1
    # distances from terra and from dock
    getDistance $distTerra 1 $bubbleGate
    getDistance $distDock STARDOCK $bubbleGate
    # a little formatting so our output looks somewhat decent
    getLength $bubbleGate $len
    setVar $padleft ""
    while ($len < 5)
      setVar $padLeft $padLeft & " "
      add $len 1
    end
    setVar $padSize ""
    getLength $bubbleSectorCnt $len
    while ($len < 3)
      setVar $padSize $padSize & " "
      add $len 1
    end
    echo ansi_12 "*!!!! " ANSI_15 "Bubble " ANSI_14 $padLeft $bubbleGate  ANSI_15 " Contains "  ANSI_11 $padSize $bubbleSectorCnt ANSI_15 " Sectors" ANSI_12 " !!!!"
    setVar $dispWarpCnt sector.warpcount[$bubbleGate]
    setVar $i 1
    write GAMENAME & "_bubbleSectors" & ".txt" "Gateway:  " & $bubbleGate & "  (" & $dispWarpCnt & "-Warps) - " & $bubbleSectorCnt & " Sectors, Hop:  " & $distTerra & " From Terra, " & $distDock & " From Dock"
    while ($i <= $bubbleSectorCnt)
      write GAMENAME & "_bubbleSectors" & ".txt"  $atTop[$i]
      add $i 1
    end
    write GAMENAME & "_bubbleSectors" & ".txt" " "
    # return to topQueue
    return