getTime $start
echo ANSI_15 "**Beginning NEARESTDE search at " $start
setVar $nearestDE SECTORS
setVar $distToDE SECTORS
setArray $que SECTORS
setArray $distance SECTORS
# Begin with a falsely high distance
setVar $i 1
while ($i <= SECTORS)
   setVar $distToDE[$i] 1000
   add $i 1
end
echo ANSI_15 "**Beginning NEARESTDE search."
setVar $i 1
while ($i <= SECTORS)
   if (SECTOR.WARPCOUNT[$i] = 1)
      echo "*Assigning DE " $i
      setVar $nearestDE[$i] $i
      setVar $distToDE[$i] 0
      gosub :bfs
   end
   add $i 1
end
echo "*Setting Params..."
setVar $i 1
while ($i <= SECTORS)
   getSectorParameter $i "NEARESTDE" $oldDE
   if ($oldDE <> $nearestDE[$i])
      getDistance $dist1 $i $oldDE
      getDistance $dist2 $i $nearestDE[$i]
      echo "*Updating NEARESTDE for sector " $i " from " $oldDE " (" $dist1 ") to " $nearestDE[$i] " (" $dist2 ")"
      setSectorParameter $i "NEARESTDE" $nearestDE[$i]
   end
   add $i 1
end
echo "*Complete.*Started: " $start ", Ended: " TIME "*"
halt

:bfs
setArray $checked SECTORS
setVar $checked[$i] TRUE
setVar $distance[$i] 0
setVar $que[1] $i
setVar $top 1
setVar $bottom 1
while ($bottom <= $top)
   setVar $focus $que[$bottom]
   setVar $j 1
   while ($j <= SECTOR.WARPINCOUNT[$focus])
      setVar $adjacent SECTOR.WARPSIN[$focus][$j]
      if ($checked[$adjacent] = FALSE)
         setVar $checked[$adjacent] TRUE
         if (($distance[$focus] + 1) < $distToDE[$adjacent])
            setVar $nearestDE[$adjacent] $i
            setVar $distance[$adjacent] ($distance[$focus] + 1)
            setVar $distToDE[$adjacent] $distance[$adjacent]
            add $top 1
            setVar $que[$top] $adjacent
         end
      end
      add $j 1
   end
   add $bottom 1
end
echo " - Que depth was " $top
return

setVar $startingSector 1  // start at Terra for this search
setVar $que[1] $startingSector
setVar $top 1
setVar $bottom 1
while ($bottom <= $top)
   setVar $focus $que[$bottom]  // focus on the next working item
   # Note: This is the clearest point to implement your search criteria
   # Let's say I'm looking for any sector with anyone's fig in it
   if (SECTOR.FIGS.QUANTITY[$focus] > 0)
      # Many scripts would jump out here, like "goto :figFound"
      echo "*Figs in sector " $focus
   end  // That's it for the search portion
   #  $focus is the working item, let's add its adjacents
   setVar $i 1  // $i is an iterator, a variable to track which warp of $focus we are currently working on
   while ($i <= SECTOR.WARPCOUNT[$focus])
      setVar $adjacent SECTOR.WARPS[$focus][$i]  // so when $i is 1, we're checking if the 1st warp has been seen before
      if ($previouslyQueued[$adjacent] = FALSE)
         # An unqueued adjacent has just been found, it goes on top, to be tested later
         add $top 1  // We have to increment $top so we know where to stick this unseen sector
         setVar $que[$top] $adjacent  // now, in due course, this sector will be the focus
         setVar $previouslyQueued[$adjacent] = TRUE  // haha, I bet you forgot this step, very important, grasshoppa
      end
      add $i 1  // now the next warp/adjacent of $focus will be tested
   end  // all of that working sector's adjacents have been queued
   add $bottom 1  // now the next sector will be made the focus, so it's warps/adjacents will be tested
end