# map

setVar $version "Map v .1"

:windowSetup
setVar $Window 1
Window MAP 400 375 "      " & $version & "  by Promethius    " ONTOP
setVar $plotFrom CURRENTSECTOR


:begin
setVar $i 1
while ($i <= 6)
   setVar $line[$i] ""
   setVar $line2[$i] ""
   setVar $cs[$i] 0
   add $i 1
end
setVar $top ""
setVar $bottom ""
setVar $Window "* Use ~ to activate options *"
setWindowContents MAP $Window & "*"

if ($option = "c")
   setVar $plotFrom CURRENTSECTOR
elseif ($option = "f")
   setVar $plotFrom $hit
end
setVar $cnt 1
while ($cnt <= sector.warpcount[$plotFrom])
   if (sector.warps[$plotFrom][$cnt] > 0)
      setVar $cs[$cnt] sector.warps[$plotFrom][$cnt]
   end
  add $cnt 1
end

# get warp sectors 1-3 from adjacent sectors and format
:display
   setVar $i 1
  while ($i <= 6)
     setVar $idx 1
     while ($idx <= 3)
        if ($cs[$idx] > 0)
           setVar $tmp $cs[$idx]
           if (sector.warps[$tmp][$i] <> $plotFrom)
              if (sector.warps[$tmp][$i] > 0)
                 setVar $str sector.warps[$tmp][$i]
                 gosub :format10
                 setVar $line[$i] $line[$i] & $str
              else
                 setVar $line[$i] $line[$i] & "         |"

               end
            else
                setVar $str "{" & $plotFrom & "}"
                gosub :format10
                setVar $line[$i] $line[$i] & $str
           end
        else
          setVar $line[$i] $line[$i]  & "               "
        end
        add $idx 1
     end
     add $i 1
end


# setup top 3 adjacent sectors to plotted sector for display
setVar $i 1
while ($i <= 3) and ($cs[$i] > 0)
    setVar $str $cs[$i]
       gosub :format10
    setVar $top $top & $str
    add $i 1
end

# get warp sectors 4-6 from adjacent sectors and format
  setVar $i 1
  while ($i <= 6)
     setVar $idx 4
     while ($idx <= 6) and ($cs[$idx] > 0)
           setVar $tmp $cs[$idx]
           if (sector.warps[$tmp][$i] <> $plotFrom)
              if (sector.warps[$tmp][$i] > 0)
                 setVar $str sector.warps[$tmp][$i]
                 gosub :format10
                 setVar $line2[$i] $line2[$i] & $str
              else
                 setVar $line2[$i] $line2[$i] & "         |"
              end
            else
                setVar $str "{" & $plotFrom & "}"
                gosub :format10
                setVar $line2[$i] $line2[$i] & $str
           end
        add $idx 1
     end
     add $i 1
end

# setup bottom 3 adjacent sectors to plotted sector for display
setVar $i 4
while ($i <= 6) and ($cs[$i] > 0)
       setVar $str $cs[$i]
             gosub :format10
       setVar $bottom $bottom & $str
   add $i 1
end
setVar $botLine ""
setVar $topLine "               \       |      /"
if (sector.warpcount[$plotFrom] = 1)
    setVar $topLine "               \"
elseif (sector.warpcount[$plotFrom] = 2)
    setVar $topLine "               \       |"
elseif (sector.warpcount[$plotFrom] = 4)
    setVar $botLine "               /"
elseif (sector.warpcount[$plotFrom] = 5)
    setVar $botLine "               /       |"
elseif (sector.warpcount[$plotFrom] = 6)
    setVar $botLine "               /       |      \"
end
:displayWindow
  setVar $window $window & "**     " & $line[1] & "*     " & $line[2] & "*     " & $line[3] & "*"
  setVar $window $window & "     " & $line[4] &  "*     " & $line[5] & "*     " & $line[6] & "*"
  setVar $window $window & "*     " & $top & "*"
  setVar $window $window & $topLine
  setVar $str "{ " & $plotFrom & " }"
  gosub :format10
  setVar $window $window & "*                 " & $str & "*"
  setVar $window $window & $botLine
  setVar $window $window  & "*     " & $bottom & "*"
  setVar $window $window & "     " & $line2[6] & "*     " & $line2[5] & "*     " & $line2[4] & "*"
  setVar $window $window & "     " & $line2[3] &  "*     " & $line2[2] & "*     " & $line2[1] & "*"
  setwindowContents MAP $window


if ($option = "c") or ($option = "f")
  goto :contDisplay
end
killtrigger opt
setTextOutTrigger opt :options "~"
pause
:options
  echo "**" ANSI_12 " Enter C for displaying of current sector when moving*"
  echo ANSI_12 " f - for fig hit sector display, or enter a sector number.*"
  getConsoleInput $Option
  isNumber $test $Option
  if ($test)
     if ($option > 0) and ($option <= SECTORS)
     setVar $plotFrom $option
     goto :begin
     else
       echo ANSI_12 "**Sector plot must be from 1 to " SECTORS "!!!!!"
       echo ANSI_12 "*Press any key to continue*"
       getConsoleInput $anyKey singlekey
       goto :options
     end
  else
    goto :contDisplay
  end

:contDisplay
   killalltriggers
   if ($option = "c")
      setTextTrigger cmd :begin "Command [TL="
   else
      setTextTrigger fig :figHit "entered sector"
   end
   setTextOutTrigger opt :options "~"
   pause

:figHit
   getword currentline $hit 5
   stripText $hit ":"
   goto :begin


# gosubs

:format10
  getLength $str $len
  while ($len < 10)
      setVar $str " " & $str
      add $len 1
  end
  return