#  ------------------------------------------------------------ -------
# Dnyarri (Singularity)'s nearest unfigged sector finder.
# Useful little script that takes advantage of 2.04's BFS function
# to find the nearest unfigged sector in your DB. Requires ZTM.
# Uses Quickfig's FIGSEC parameter for fig tracking so you'll need
# that too.
#
# More scripts and info at http://www.navhaz.com
#  ------------------------------------------------------------ -------
# Search from where?
:get_start
getInput $start "Sector to search from (ENTER = your TA)? "
if ($start = "")
     gosub :get_current_sector
     setVar $start $current_sector
end
isNumber $result $start
if ($result < 1)
     goto :get_start
end
if ($start < 1) OR ($start > SECTORS)
     goto :get_start
end

# Do the search
echo ANSI_13 & "**Searching...*"
getNearestWarps $stack $start
setVar $idx 1
while ($idx <= $stack)
     setVar $this_sec $stack[$idx]
     getSectorParameter $this_sec "FIGSEC" $figged
     if ($figged = TRUE) AND (PORT.EXISTS[$this_sec] = TRUE) AND (PORT.BUYFUEL[$this_sec] = FALSE) AND ($this_sec <> RYLOS) AND ($this_sec <> ALPHACENTAURI)
           echo ANSI_14 & "Nearest figged fuel port to " & ANSI_11 & $start & ANSI_14 " is " & ANSI_10 & $stack[$idx] & ".*"
           if ($start = $this_sec)
                setVar $course_idx 0
                setVar $lane[1] $this_sec
           else
                getCourse $lane $start $this_sec
           end
           setVar $course_idx 1
           while ($course_idx <= ($lane+1))
                if ($course_idx = 1)
                      echo ANSI_2 & $lane[$course_idx]
                else
                      echo ANSI_9 & $lane[$course_idx]
                end
                if ($course_idx <= $lane)
                     # Print hop seperator if we should
                      echo ANSI_11 & ">"
                end
                add $course_idx 1
           end
           echo "**"
           send #145
           halt
     end
     add $idx 1
end

echo ANSI_14 & "No figged fuel ports found!**"
send #145

#  ------------------------------------------------------------ -------
halt
#  ------------------------------------------------------------ -------
# Get current sector - I'd use CURRENTSECTOR but it's wrong a lot.
:get_current_sector
setVar $current_sector 0

:current_sector_loop
isNumber $result $current_sector
if ($result < 1)
     send "/"
     waitFor #179
     setVar $line CURRENTLINE
     replacetext $line #179 " "
     getWord $line $current_sector 2
     goto :current_sector_loop
end
if ($current_sector < 1) OR ($current_sector > SECTORS)
     send "/"
     waitFor #179
     setVar $line CURRENTLINE
     replacetext $line #179 " "
     getWord $line $current_sector 2
     goto :current_sector_loop
end
return
#  ------------------------------------------------------------ -------